使用 Gradle

2026-08-13 22:43:29 +08:00 · 2018-01-19 17:23:01 +08:00
parent e242ce1997
commit 7d155df323
3 changed files with 92 additions and 155 deletions
--- a/build.gradle
+++ b/build.gradle
@@ -0,0 +1,91 @@
+group = 'com.hiczp'
+version = '0.0.1'
+description = 'Bilibili android client API library written in Java'
+
+apply plugin: 'idea'
+apply plugin: 'java'
+apply plugin: 'maven'
+
+repositories {
+    maven { url 'http://maven.aliyun.com/nexus/content/groups/public/' }
+    mavenCentral()
+}
+
+dependencies {
+    // https://mvnrepository.com/artifact/com.squareup.retrofit2/retrofit
+    compile group: 'com.squareup.retrofit2', name: 'retrofit', version: '2.3.0'
+    // https://mvnrepository.com/artifact/com.squareup.retrofit2/converter-gson
+    compile group: 'com.squareup.retrofit2', name: 'converter-gson', version: '2.3.0'
+    // https://mvnrepository.com/artifact/com.google.code.gson/gson
+    compile group: 'com.google.code.gson', name: 'gson', version: '2.8.2'
+    // https://mvnrepository.com/artifact/com.squareup.okhttp3/logging-interceptor
+    compile group: 'com.squareup.okhttp3', name: 'logging-interceptor', version: '3.9.1'
+    // https://mvnrepository.com/artifact/org.slf4j/slf4j-api
+    compile group: 'org.slf4j', name: 'slf4j-api', version: '1.7.25'
+    // https://mvnrepository.com/artifact/io.netty/netty-all
+    compile group: 'io.netty', name: 'netty-all', version: '4.1.19.Final'
+    // https://mvnrepository.com/artifact/com.google.guava/guava
+    compile group: 'com.google.guava', name: 'guava', version: '23.6-jre'
+}
+
+dependencies {
+    // https://mvnrepository.com/artifact/junit/junit
+    testCompile group: 'junit', name: 'junit', version: '4.12'
+    // https://mvnrepository.com/artifact/org.slf4j/slf4j-log4j12
+    testCompile group: 'org.slf4j', name: 'slf4j-log4j12', version: '1.7.25'
+}
+
+task sourcesJar(type: Jar, dependsOn: classes) {
+    description 'Package source code to jar,'
+    classifier = 'sources'
+    from sourceSets.main.allSource
+}
+
+task javadocJar(type: Jar, dependsOn: javadoc) {
+    description 'Package javadoc to jar,'
+    classifier = 'javadoc'
+    from javadoc
+}
+
+artifacts {
+    archives sourcesJar
+    archives javadocJar
+}
+
+uploadArchives {
+    repositories {
+        mavenDeployer {
+            repository(url: 'https://oss.sonatype.org/service/local/staging/deploy/maven2/') {
+                authentication(userName: ossUsername, password: ossPassword)
+            }
+
+            pom.project {
+                name project.name
+                description project.description
+                url 'https://github.com/czp3009/bilibili-api'
+
+                scm {
+                    connection 'scm:git@github.com:czp3009/bilibili-api.git'
+                    developerConnection 'scm:git@github.com:czp3009/bilibili-api.git'
+                    url 'git@github.com:czp3009/bilibili-api.git'
+                }
+
+                licenses {
+                    license {
+                        name 'GNU GENERAL PUBLIC LICENSE Version 3'
+                        url 'https://www.gnu.org/licenses/gpl-3.0.txt'
+                    }
+                }
+
+                developers {
+                    developer {
+                        id 'czp'
+                        name 'ZhiPeng Chen'
+                        email 'czp3009@gmail.com'
+                        url 'https://www.hiczp.com/'
+                    }
+                }
+            }
+        }
+    }
+}